ConvertCoordinateX()

Syntax

Ergebnis.d = ConvertCoordinateX(x.d, y.d [, Quelle, Ziel])

Konvertiert einen Punkt von einem Koordinatensystem in ein anderes innerhalb der Vektorzeichnen-Ausgabe. Diese Funktion gibt die X-Koordinate der Umwandlung zurück. Die Y-Koordinate kann mit der ConvertCoordinateY() Funktion ermittelt werden.

Parameter

x.d, y.d

Gibt die Koordinaten des zu konvertierenden Punktes in Bezug auf das Quell-Koordinatensystem an.

Quelle, Ziel (optional)

Geben die Quell- und Ziel-Koordinaten für die Konvertierung an. Jede kann einer der folgenden Werte sein: #PB_Coordinate_Device: Das Koordinatensystem der Ausgabe-Einheit #PB_Coordinate_Output: Das Koordinatensystem, wie es mit der Zeichenausgabe-Funktion erstellt wurde #PB_Coordinate_User : Das Koordinatensystem für Punkte im Zeichenpfad #PB_Coordinate_Source: Das Koordinatensystem für die Vektorzeichnen-Quelle Die Standard-Konvertierung erfolgt von #PB_Coordinate_User in #PB_Coordinate_Output.

Rückgabewert

Gibt die X-Koordinate des Punktes im Ziel-Koordinatensystem zurück.

Anmerkungen

Siehe den Vektorzeichnen Überblick für eine Einführung in die verschiedenen Koordinatensysteme.

Beispiel

  ; Diese Beispiel zeichnet einen Punkt an der Mausposition, selbst in einem veränderten
  ; Koordinatensystem - durch Abbilden ("mapping") der Koordinaten vom Gerätesystem 
  ; ("device", in Pixel) das Benutzersystem ("user", in Punkten)
  ;
  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)   
    
    Repeat
      Event = WaitWindowEvent()
      
      If Event = #PB_Event_Gadget And EventGadget() = 0 And EventType() = #PB_EventType_LeftButtonDown
        
        If StartVectorDrawing(CanvasVectorOutput(0, #PB_Unit_Point))
          RotateCoordinates(0, 0, 30)
          
          CanvasX = GetGadgetAttribute(0, #PB_Canvas_MouseX)
          CanvasY = GetGadgetAttribute(0, #PB_Canvas_MouseY)
          
          DrawingX = ConvertCoordinateX(CanvasX, CanvasY, #PB_Coordinate_Device, #PB_Coordinate_User)
          DrawingY = ConvertCoordinateY(CanvasX, CanvasY, #PB_Coordinate_Device, #PB_Coordinate_User)
          
          AddPathCircle(DrawingX, DrawingY, 10)
          VectorSourceColor(RGBA(Random(255), Random(255), Random(255), 255))
          FillPath()
        
          StopVectorDrawing()
        EndIf
        
      EndIf
      
    Until Event = #PB_Event_CloseWindow
  EndIf

Siehe auch

ResetCoordinates(), TranslateCoordinates(), ScaleCoordinates(), RotateCoordinates(), SkewCoordinates(), FlipCoordinatesX(), FlipCoordinatesY(), ConvertCoordinateY()

Unterstützte OS

Alle