KeyboardInkey()

Syntax

String$ = KeyboardInkey()

Gibt das zuletzt eingegebene Zeichen zurück - sehr nützlich, wenn effiziente Tastatureingabe für ein Spiel (z.B. Name in einem HighScore, in einer Game-Konsole, etc.) erforderlich ist.

Parameter

Diese Funktion hat keine Parameter.

Rückgabewert

Das letzte eingegebene Zeichen.

Anmerkungen

Der Befehl ExamineKeyboard() muss vor dieser Funktion aufgerufen werden, um den Tastatur-Status zu aktualisieren.

Beispiel

  If InitSprite() And InitKeyboard() And OpenScreen(800, 600, 32, "")
    Repeat
      FlipBuffers()
      ClearScreen(RGB(0, 0, 0))
      
      ExamineKeyboard()
      
      ; Wenn wir die 'Backspace'-Taste drücken, löschen wir das letzte Zeichen
      ;
      If KeyboardReleased(#PB_Key_Back)  
        FullText$ = Left(FullText$, Len(FullText$)-1)
      Else
        result$=KeyboardInkey()
        If FindString("1234567890 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz", result$) ; oder die von Ihnen ausgewählten gültigen Zeichen
          FullText$ + result$
        EndIf ; den neuen Text zum aktuellen (wenn vorhanden) hinzufügen
      EndIf

      ; Ergebnis darstellen
      ;
      If StartDrawing(ScreenOutput())
          DrawingMode(1)
          FrontColor(RGB(128, 255, 0))
          DrawText(20, 20, "Gib einfach etwas Text ein...:")
          DrawText(20, 40, FullText$)
        StopDrawing()
      EndIf
    Until KeyboardPushed(#PB_Key_Escape)
  EndIf

Siehe auch

ExamineKeyboard()

Unterstützte OS

Alle