SetGadgetItemData()

Syntax

SetGadgetItemData(#Gadget, Eintrag, Wert)

Speichert den angegebenen Wert mit dem angegebenen Gadget-Eintrag. Dieser Wert kann später mit dem GetGadgetItemData() Befehl ausgelesen werden. Dies ermöglicht das Verknüpfen eines individuellen Werts mit den Einträgen eines Gadgets.

Parameter

#Gadget	Das zu verwendende Gadget.
Eintrag	Der zu verwendende Eintrag. Der erste Eintrag im Gadget hat den Index 0.
Wert	Der zu setzende Wert.

Rückgabewert

Diese Funktion gibt keinen Wert zurück.

Anmerkungen

Der gesetzte Wert bleibt zusammen mit dem Eintrag bestehen, auch wenn sich der Index des Eintrags ändert (z.B. weil andere Einträge gelöscht wurden).

Dieser Befehl arbeitet mit den folgenden Gadgets:
- ComboBoxGadget()
- ListIconGadget()
- ListViewGadget()
- PanelGadget()
- TreeGadget()

Beispiel

  ; Dieser Code verwendet SetGadgetItemData zum Speichern der Original-Position jedes
  ; Eintrags, um diesen auch noch später zu wissen, wenn sich der Index des Eintrags ändert.
  ;
  If OpenWindow(0, 0, 0, 280, 250, "SetGadgetItemData", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    ButtonGadget(0,  10, 10, 80, 20, "Add")
    ButtonGadget(1, 100, 10, 80, 20, "Remove")  
    ButtonGadget(2, 190, 10, 80, 20, "Test") 
    ListViewGadget(3, 10, 40, 260, 200)
    For i = 0 To 10
      AddGadgetItem(3, i, "Old Item "+Str(i))
      SetGadgetItemData(3, i, i)
    Next i
    
    Repeat
      Event = WaitWindowEvent()
      If Event = #PB_Event_Gadget
        item = GetGadgetState(3)
        
        Select EventGadget()        
          Case 0 ; Add          
            AddGadgetItem(3, item, "New Item")
            If item <> -1
              SetGadgetItemData(3, item, -1)
            Else
              SetGadgetItemData(3, CountGadgetItems(3)-1, -1)
            EndIf
            
          Case 1 ; Remove
            If item <> -1
              RemoveGadgetItem(3, item)
            EndIf
            
          Case 2 ; Test
            If item <> -1
              value = GetGadgetItemData(3, item)
              If value = -1
                MessageRequester("", "Its a new item.")
              Else
                MessageRequester("", "It was item number "+Str(value))
              EndIf
            EndIf
                     
        EndSelect
      EndIf
    Until Event = #PB_Event_CloseWindow
  EndIf

Siehe auch

GetGadgetItemData(), GetGadgetData(), SetGadgetData()

Unterstützte OS

Alle