AddElement()

Syntaxe

Resultat = AddElement(Liste())

Ajoute un nouvel élément vide après l'élément courant de la Liste() ou devient le premier élément si la liste est vide. Ce nouvel élément devient l'élément courant de la liste.

Arguments

Liste()

Le nom de votre variable liste, créée à l'aide de la commande NewList. Les parenthèses sont obligatoires après le nom de la liste.

Valeur de retour

Renvoie une valeur non nulle si le nouvel élément a été créé, ou zéro sinon.


La valeur renvoyée est un pointeur sur le nouvel élément.

Exemple

  ; La manière la plus simple d'utiliser AddElement
  NewList simple.w()
  AddElement(simple())    ; Crée le premier nouvel élément de la liste
  simple() = 23

  AddElement(simple())    ; La position courante est le premier élément, alors nous en ajoutons un à la deuxième position
  simple() = 45


  ; Ceci montre comment utiliser la valeur de retour de la fonction AddElement
  NewList experimentes.l()
  If AddElement(experimentes()) <> 0
    experimentes() = 12345
  Else
    MessageRequester("Erreur !", "Impossible d'allouer de la mémoire pour le nouvel élément", #PB_MessageRequester_OK)
  EndIf


  ; Une petite structure pour montrer l'utilisation du pointeur.
  Structure Programmeur
    Nom.s
    Talent.b
  EndStructure

  NewList LesProgrammeurs.Programmeur()  ; La liste qui stocke les éléments

  *Element.Programmeur = AddElement(LesProgrammeurs())
  If *Element<>0
    *Element\Nom = "David"
    *Element\Talent = 3   ; Celui-là, c'est un féru de PureBasic ! ;)
  Else
    MessageRequester("Erreur !", "Impossible d'allouer de la mémoire pour le nouvel élément", #PB_MessageRequester_OK)
  EndIf

Voir aussi

InsertElement(), DeleteElement(), ClearList()

OS Supportés

Tous